[YG Conlang Archives] > [engelang group] > messages [Date Index] [Thread Index] >

[Date Prev] [Date Next] [Thread Prev] [Thread Next]

Re: [engelang] Xorban: Termsets

I am starting to think the "core-formula" production can be safely scrapped.  Terms have to group to the right regardless if they're grouping with trees or formulas.  Here's the whole grammar, hypothetically speaking, with trees.

_Longhand Rules with Trees_

sentence := formula | explicit-sentence
explicit-sentence := illocutionary-operator formula | interjection
formula := simple-formula | term formula | foretree formula | formula aftertree
simple-formula := (C C C* | q ( C? V? )* q) VkV
aftertree := aftertree-particle | aftertree-extender aftertree
aftertree-extender := term | coordinator aftertree
aftertree-particle := hi explicit-sentence?
foretree := foretree-particle | foretree-extender foretree
foretree-extender := term | coordinator foretree
foretree-particle := he explicit-sentence?
term := unary-operator | binder formula | coordinator formula
coordinator := ( j ) VkV
binder:= ( l | r | s | x | g ) VkV
unary-operator := ( b | f | d | v | m | n ) VkV
illocutionary-operator := c VkV
interjection := w VkV
VkV := V (k V)* explicit-sentence?
V := ( a | e | i | o | u ) ( ‘ V )?
C := b | c | d | f | g | j | k | l | m | n | p | r | s | t | v | x | z


If we made a point of getting rid of every production referenced only once we'd have:

_Shorthand Rules with Trees_

sentence := formula | explicit-sentence
explicit-sentence := c VkV formula | w VkV
formula := (C C C* | q ( C? V? )* q) VkV | term formula | foretree formula | formula aftertree
aftertree := hi explicit-sentence? | term aftertree | coordinator aftertree aftertree
foretree := he explicit-sentence? | term foretree | coordinator foretree foretree
term := (b|f|d|v|m|n) VkV | (l|r|s|x|g) VkV formula | coordinator formula
coordinator := j VkV
VkV := V (k V)* explicit-sentence?
V := ( a | e | i | o | u ) ( ‘ V )?
C := b | c | d | f | g | j | k | l | m | n | p | r | s | t | v | x | z

Which brings us back to ten rules, including two types of tree!  Of course, the latter is harder to read.  And it'd be nicer to have formal names for all the word classes, incl the tree particles. So don't take this as a proposal.